Following batch creates .sql which, in turn, attempts to create table with huge number of fields - more than 5000.
Table contains field ID (primary key) plus other ("user") fields with names start with 'F'.

When total number of "user" fields ("F1", "F2", ...) exceeds 'magic number' = 5459 then FB crashes.
Checked on WI-V3.0.7.33365, WI-V4.0.0.2204.

=======
@echo off
setlocal enabledelayedexpansion enableextensions
set tmpsql=%~dpn0.sql.tmp
set fbc=C:\FB\30SS
set dbnm=c:\temp\tmp4test.fdb
set ISC_USER=SYSDBA
set ISC_PASSWORD=masterkey
@rem theshold for FB 3.x and FB 4.x: set FLD_COUNT=5460 -- crashes since this value
set FLD_COUNT=5459
 
if exist !dbnm! del !dbnm!
if exist !dbnm!.delta del !dbnm!.delta
 
echo create database 'localhost:!dbnm!'; | !fbc!\isql -q -z
!fbc!\gfix -w async !dbnm!
 
echo recreate table tdata(id bigint primary key > !tmpsql!
(
    for /l %%i in (1 1 !FLD_COUNT!) do (
        echo ,f%%i bigint
    )
) >>!tmpsql!
echo ^); >>!tmpsql!
echo commit; >>!tmpsql!
 
echo !date! !time! point before create table
!fbc!\isql localhost:!dbnm! -i !tmpsql!
echo !date! !time! point after create table
 
echo update or insert into tdata values( 1 >!tmpsql!
(
    for /l %%i in (1 1 !FLD_COUNT!) do (
        echo ,%%i
    )
) >>!tmpsql!
echo ^) matching(id^); >>!tmpsql!
echo commit; >>!tmpsql!
 
echo !date! !time! point before update or insert
!fbc!\isql localhost:!dbnm! -i !tmpsql!
echo !date! !time! point after update or insert
=======